* Margin Control Macros, by John Woodruff. April 2000.
*
*F01]......[TempLM>] Set temporary left margin at next tab stop to right
*                    of current margin, if permitted by file mode
[F01]<Esc >[TempLM>]<N>
		^OG
*
*F02]......[ParaFmt] Reformat current paragraph if permitted by file mode;
*                    "hard" reformatting is controlled separately by ^OY
*                    toggle
[F02]<Esc >[ParaFmt]<N>
		^B[K5]
*
*^01]......[>I<:<O>] shrink both margins by 4 characters (I)nward or expand
*                    by 4 characters (O)utward
[^01]<Esc >[>I<:<O>]<N>
		[Esc]:
		[Esc]!_
		[Esc]I
		[Esc]/L4+
		[Esc]/R4-
		[Esc]!]
		[Esc]O
		[Esc]/L4-
		[Esc]/R4+
*
*^02]......[M4:asdf] move a margin 4 characters: left margin (a)left or
*                    (s)right; right margin (d)left or (f)right
[^02]<Esc >[M4:asdf]<N>
		[Esc]:
		[Esc]!_
		[Esc]A
		[Esc]/L4-
		[Esc]!]
		[Esc]S
		[Esc]/L4+
		[Esc]!]
		[Esc]D
		[Esc]/R4-
		[Esc]!]
		[Esc]F
		[Esc]/R4+
*
*^08]......[TopRulr] set ruler if found in text at top of file, return
*                    to current edit point (Additional notes: Coded to
*                    call ^F10 below. TopRulr is a way to keep a default
*                    ruler handy. I use page 1 for rulers, comments,
*                    whatever, then print starting with page 2 numbered
*                    as page 1).
[^08]<Esc >[TopRulr]<QN>
		^QR
		[Esc]&&^F0^QP
*
*^09]......[Rlr2Txt] create 2 ruler lines at and below current line, #1
*                    for margins and #2 for Varitabs; if no tabs are set,
*                    will put a ! in col 1 of line #2; on exit, file
*                    mode=/D, Insert=ON, Varitab=ON
[^09]<Esc >[Rlr2Txt]<QN>
		^KE/D[Enter]
		[Esc]*x
		[Esc]*i
		[Esc]*V^QS^N^NR^OF^EL[Enter]
		[Esc]*X
		[Esc](16)
		[Esc]1[Tab]!^S
		[Esc]-X
		[Esc]!1
		[Esc]X^X^QS^V^OX
*
*^10]......[Txt2Rlr] with cursor on #1 of 2 ruler lines, set margins
*                    and tabs; CR/LF must immediately follow last !;
*                    for no tabs, #2 should be a blank line (OK to
*                    have a ! in col 1); on exit, file mode=/D,
*                    auto Format=OFF, Insert=ON
[^10]<Esc >[Txt2Rlr]<QN>
		^KE/D[Enter]
		[Esc]*i
		[Esc]*f^ON*[Enter]^QS
		[Esc]~L>^OL[Enter]
		[Esc]~R>^OR[Enter][Enter]
		[Esc]=^M2
		[Esc]1
		[Esc]~!>^OI[Enter]^D
		[Esc]=^M2
		[Esc]!1
		[Esc]2[Enter]^V
*
* These ruler lines can be commented internally, as long as you don't
* use the L, R, and ! characters, and don't go beyond the final ! on
* the tab line.
*
* Example:
*
*          L  ruler for section 1 table                                R
*          item description                !dollars / qty  !
*
* End of Macro